** Shingles Data Set (NKNW 8.9 & 10.14);

OPTIONS LINESIZE=75 NOCENTER NONUMBER NODATE;

TITLE 'Roofing Shingle Sales';

PROC IMPORT DATAFILE = 'F:\SAS\Shingles.txt'
  DBMS = dlm OUT = shingles REPLACE;
  
PROC FORMAT;
  VALUE $trainfmt 'TRUE' = 'Training'
                  'FALSE' = 'Test';
  
  VALUE potfmt 1 = 'Low'
               2 = 'Moderate'
               3 = 'High'
               . = 'Missing'
               OTHER = 'Miscoded';

  VALUE  competefmt LOW-<10 = 'Low'
                     10-HIGH = 'High';

DATA shingles2;
  set shingles;
      
  FORMAT potentcat $8. training $5. compete $4.;
    
  compete = put(brands,competefmt.);

  IF potential > 15 then potentcat = 'High';
  ELSE IF potential < 6 then potentcat = 'Low';
  ELSE potentcat = 'Moderate';

  IF potential > 15 then pot = 3;
  ELSE IF potential < 6 then pot = 1;
  ELSE pot = 2;

  IF _N_ < 27 THEN training = 'TRUE';
    ELSE training = 'FALSE';

  obsno = _N_;

RUN;

OPTIONS PAGESIZE = 20; /* for sizing output for LaTeX slides */

PROC CHART DATA = shingles2;

  TITLE 'Breakdown of Region Potential Classes';
  FORMAT training $trainfmt. pot potfmt. ;
  
  HBAR potentcat;
  HBAR potentcat / FREQ;
  HBAR potentcat / CFREQ;
  VBAR potentcat / SUMVAR = SALES TYPE = MEAN;
  VBAR potentcat  / GROUP = training;
  PIE potentcat;
  STAR potentcat;

RUN;

PROC PLOT;
  PLOT sales*promotion;   /* y-var * x-var */
  PLOT sales*brands='+';
  PLOT sales*accounts=pot;
  
  TITLE 'Sales Relationships';
  FORMAT training $trainfmt. pot potfmt. ;

RUN;



FILENAME grafout 'F:\SAS\hbarpot.eps'; 


goptions RESET=ALL
         device=pscolor
         GSFNAME=grafout 
         GSFMODE=REPLACE
         FTEXT=swissb
         HSIZE = 7IN
         VSIZE = 4IN;
  

PROC GCHART DATA = shingles2;

  TITLE 'Breakdown of Region Potential Classes';
  FORMAT training $trainfmt. pot potfmt. ;
  
  HBAR potentcat / FREQ;
  
RUN;

FILENAME grafout2 'F:\SAS\vbarpot.eps'; 

goptions RESET=ALL
         device=pscolor
         GSFNAME=grafout2 
         GSFMODE=REPLACE
         FTEXT=swissb
         HSIZE = 7IN
         VSIZE = 5IN;;
  


PROC GCHART DATA = shingles2;

  TITLE 'Breakdown of Region Potential Classes';
  FORMAT training $trainfmt. pot potfmt. ;
  
  VBAR potentcat / FREQ;
  
RUN;

FILENAME grafout3 'F:\SAS\salespromo.eps'; 
goptions RESET=ALL
         device=pscolor
         GSFNAME=grafout3
         GSFMODE=REPLACE
         FTEXT=swissb
         HSIZE = 7IN
         VSIZE = 5IN;

PROC GPLOT DATA = shingles2;

  PLOT sales*promotion;
  TITLE 'Sales vs Promotion';
  
RUN;

FILENAME grafout4 "F:\SAS\salespromo2.eps"; 
goptions RESET=ALL
         device=pscolor
         GSFNAME=grafout4
         GSFMODE=REPLACE
         FTEXT=swissb
         HSIZE = 7IN
         VSIZE = 5IN;
         
axis1 label = ("Promotion ($1000)");

axis2 label = ( 'Sales' justify=right '(1000s of squares)' )
      width = 3;
      
footnote j=l "Shingle Sales Data";

PROC GPLOT DATA = shingles2;

  PLOT sales*promotion / HAXIS=axis1 
                         VAXIS=axis2;
  TITLE 'Sales vs Promotion';
  
RUN;

* proc gdevice catalog=sashelp.devices;

* RUN;

QUIT;