* Tables examples for PROC FREQ;

OPTIONS LINESIZE=75 NOCENTER NONUMBER NODATE;

PROC FORMAT;
  VALUE genderfmt 1 = 'Men'
                  2 = 'Women';
  VALUE statusfmt 1 = 'Admitted'
                  0 = 'Rejected';

DATA berkeley;

  INPUT major $ gender status count;
  LABEL major = 'Major Applied to'
        gender = 'Gender'
        status = 'Admittance Status';
    DATALINES;
      A      1   1     511
      A      1   0     314
      A      2   1      89
      A      2   0      19
      B      1   1     353
      B      1   0     207
      B      2   1      17
      B      2   0       8
      C      1   1     120
      C      1   0     205
      C      2   1     202
      C      2   0     391
      D      1   1     138
      D      1   0     279
      D      2   1     131
      D      2   0     244
      E      1   1      54
      E      1   0     137
      E      2   1      94
      E      2   0     299
      F      1   1      22
      F      1   0     351
      F      2   1      24
      F      2   0     317
    ;

PROC FREQ DATA = berkeley;
  WEIGHT count;
  TABLES major gender status / NOCUM;
  TABLES gender*status / CHISQ;
  TABLES major * gender * status / CHISQ;
  FORMAT gender genderfmt. status statusfmt.;
  TITLE 'With FORMAT Statement';
  
PROC FREQ DATA = berkeley;
  WEIGHT count;
  TABLES major gender status / NOCUM;
  TABLES gender*status / CHISQ;
  TITLE 'Without FORMAT Statement';

PROC FREQ DATA = berkeley;
  WEIGHT count;
  BY major;
  TABLES gender*status / CHISQ;
  FORMAT gender genderfmt. status statusfmt.;
  TITLE 'Admittance Status by Major';
  
RUN;

PROC FREQ DATA = berkeley;
  WEIGHT count;
  TABLES major*gender major*status;
  FORMAT gender genderfmt. status statusfmt.;
  
RUN;

PROC TABULATE DATA = berkeley;
  FREQ count;
  CLASS major gender status;
  FORMAT gender genderfmt. status statusfmt.;
  TABLE major , gender * status;
  TITLE 'PROC TABULATE 3-way Table';

RUN;


PROC FREQ DATA = berkeley;
  WEIGHT count;
  TABLES major*gender / NOROW NOPERCENT;
  TABLES major*status / NOCOL NOPERCENT;
  FORMAT gender genderfmt. status statusfmt.;
  TITLE '2-way tables';
  
RUN;

TITLE 'Preventing Future Strokes with Aspirin';

DATA aspirin;
  INPUT count treatment $ stroke $ ;
  LABEL treatment = 'Stroke Treatment'
        stroke = 'Another Stroke';
  DATALINES;
    63  Aspirin No
    15  Aspirin Yes
    43  Placebo No
    34  Placebo Yes
  ;

PROC FREQ;
  WEIGHT count;
  TABLES treatment * stroke / NOCOL NOPERCENT CHISQ RELRISK;

RUN;